Desenvolver um algoritmo e implementar um programa em VISUALG que leia o nome e a nota de uma turma de 30 alunos para apresentar a maior e menor nota. Ao final o programa deverá informar o nome e a nota correspondente de cada aluno, assim como a o nome e a nota do aluno com maior nota e menor nota e a média das notas da turma.

1

Respostas

A melhor resposta!
2014-04-23T12:30:15-03:00
// Olá Lily, terminei, foi um pouco custoso, mas está funcionando..apesar de algumas
// redundâncias no código.


algoritmo "notas_turma"

var  nome: vetor[1..30] de caracter
     nota: vetor[1..30] de  real
     somaNotas, media, maior, menor : real
     i, posicaoMaior, posicaoMenor : inteiro

inicio
     maior <- 0
     menor <- 9999999
     somaNotas <- 0
    
     para i de 1 ate 30 faca
         escreva(i," - Digite o nome do aluno: ")
         leia(nome[i])
         escreva(i," - Digite a nota do aluno: ")
         leia(nota[i])
         escreval("======================================")

         somaNotas <- somaNotas + nota[i]

         se(nota[i] >= maior) entao
            maior <- nota[i]
            posicaoMaior <- i
         fimse
         se(nota[i] <= menor) entao
            menor <- nota[i]
            posicaoMenor <- i
         fimse
     fimpara
     escreval("======================================")
     escreval("======================================")

     para i de 1 ate 30 faca
         escreval(i,"º Aluno: ", nome[i])
         escreval("Nota: ", nota[i])
     fimpara
    
     escreval("======================================")
     escreval("======================================")
    
     escreval("========ALUNO COM MAIOR NOTA:=========")
     escreval("Nome: ", nome[posicaoMaior])
     escreval("Nota: ", maior)
     escreval("======================================")
     escreval("======================================")
     escreval("========ALUNO COM MENOR NOTA:=========")
     escreval("Nome: ", nome[posicaoMenor])
     escreval("Nota: ", menor)
     escreval("======================================")
     escreval("======================================")

     media <- somaNotas / 30

     escreval("A média da Turma é: ", media)
     escreval("======================================")
fimalgoritmo

3 5 3